Tutorial do Terraform

Neste tutorial, você verá como implantar uma função HTTP fazendo upload de um arquivo ZIP do código-fonte da função em um bucket do Cloud Storage usando o Terraform para provisionar os recursos. O Terraform é uma ferramenta de código aberto que permite provisionar recursos Google Cloud com arquivos de configuração declarativos.

Neste tutorial, usamos uma função HTTP Node.js como exemplo, mas ela também funciona com funções HTTP Python, Go e Java. As instruções são as mesmas, independentemente do ambiente de execução que você está usando.

Ao implantar com o Terraform, é necessário fazer upload do arquivo de origem compactado da função para um bucket do Cloud Storage (source_archive_bucket) e especificar o nome do objeto do Cloud Storage (source_archive_object) na configuração do Terraform. Para mais informações, consulte o guia de especificações do Terraform.

O Cloud Run functions copia o arquivo de origem que você faz upload no source_archive_bucket para um bucket no seu projeto com um nome que segue o formato gcf-v2-sources-PROJECT_NUMBER-REGION(Cloud Run functions) ou gcf-sources-PROJECT_NUMBER-REGION Cloud Run functions (1ª geração). Essa configuração varia de acordo com a dependência da CMEK.

Como configurar o ambiente

Neste tutorial, você executa comandos no Cloud Shell. O Cloud Shell é um ambiente com a Google Cloud CLI pré-instalada, incluindo a Google Cloud CLI e os valores já definidos para o projeto atual. O Cloud Shell pode demorar vários minutos para ser inicializado.

Abra o Cloud Shell

Como preparar o aplicativo

No Cloud Shell, execute as seguintes etapas:

Clone o repositório de aplicativos de amostra para sua instância do Cloud Shell:

git clone https://github.com/terraform-google-modules/terraform-docs-samples.git

Mude para o diretório que contém os exemplos de código de exemplo das funções do Cloud Run:

cd terraform-docs-samples/functions/basic

A amostra Node.JS usada neste tutorial é uma função HTTP básica "Hello World". Este é o arquivo main.tf:

terraform {
  required_providers {
    google = {
      source  = "hashicorp/google"
      version = ">= 4.34.0"
    }
  }
}

resource "random_id" "default" {
  byte_length = 8
}

resource "google_storage_bucket" "default" {
  name                        = "${random_id.default.hex}-gcf-source" # Every bucket name must be globally unique
  location                    = "US"
  uniform_bucket_level_access = true
}

data "archive_file" "default" {
  type        = "zip"
  output_path = "/tmp/function-source.zip"
  source_dir  = "functions/hello-world/"
}
resource "google_storage_bucket_object" "object" {
  name   = "function-source.zip"
  bucket = google_storage_bucket.default.name
  source = data.archive_file.default.output_path # Add path to the zipped function source code
}

resource "google_cloudfunctions2_function" "default" {
  name        = "function-v2"
  location    = "us-central1"
  description = "a new function"

  build_config {
    runtime     = "nodejs22"
    entry_point = "helloHttp" # Set the entry point
    source {
      storage_source {
        bucket = google_storage_bucket.default.name
        object = google_storage_bucket_object.object.name
      }
    }
  }

  service_config {
    max_instance_count = 1
    available_memory   = "256M"
    timeout_seconds    = 60
  }
}

resource "google_cloud_run_service_iam_member" "member" {
  location = google_cloudfunctions2_function.default.location
  service  = google_cloudfunctions2_function.default.name
  role     = "roles/run.invoker"
  member   = "allUsers"
}

output "function_uri" {
  value = google_cloudfunctions2_function.default.service_config[0].uri
}

Inicialize o Terraform

No diretório terraform-docs-samples/functions/basic que contém o arquivo main.tf, execute este comando para adicionar os plug-ins necessários e criar o diretório .terraform:

terraform init

Aplique a configuração do Terraform:

No mesmo diretório terraform-docs-samples/functions/basic que contém o arquivo main.tf, implante a função aplicando a configuração. Quando solicitado, digite yes.

terraform apply

Testar a função

Quando a implantação da função estiver concluída, anote a propriedade ou encontre-a usando o seguinte comando:
```
gcloud functions describe function-v2 --gen2 --region=us-central1 --format="value(serviceConfig.uri)"
```
Faça uma solicitação a este URL para ver a mensagem "Hello World" da sua função. Observe que a função é implantada exigindo autenticação. Portanto, é necessário fornecer as credenciais na sua solicitação:
```
curl -H "Authorization: Bearer $(gcloud auth print-identity-token)" YOUR_FUNCTION_URL
```

Limpar

Depois de concluir o tutorial, exclua tudo o que foi criado para que você não tenha custos adicionais.

O Terraform permite remover todos os recursos definidos no arquivo de configuração executando o comando terraform destroy no diretório terraform-docs-samples/functions/basic que contém o arquivo main.tf:

terraform destroy

Digite yes para permitir que o Terraform exclua seus recursos.