# CPackIFW

This module looks for the location of the command line utilities supplied with the Qt Installer Framework (QtIFW).

The module also defines several commands to control the behavior of the CPack `IFW` generator.

## Overview

CPack `IFW` generator helps you to create online and offline binary cross-platform installers with a graphical user interface.

CPack IFW generator prepares project installation and generates configuration and meta information for QtIFW tools.

The QtIFW provides a set of tools and utilities to create installers for the supported desktop Qt platforms: Linux, Microsoft Windows, and Mac OS X.

You should also install QtIFW to use CPack `IFW` generator. If you don’t use a default path for the installation, please set the used path in the variable `QTIFWDIR`.

## Variables

You can use the following variables to change behavior of CPack `IFW` generator.

### Debug

`CPACK_IFW_VERBOSE`

  Set to `ON` to enable addition debug output. By default is `OFF`.

### Package

`CPACK_IFW_PACKAGE_TITLE`

  Name of the installer as displayed on the title bar. By default used `CPACK_PACKAGE_DESCRIPTION_SUMMARY`.

`CPACK_IFW_PACKAGE_PUBLISHER`

  Publisher of the software (as shown in the Windows Control Panel). By default used `CPACK_PACKAGE_VENDOR`.

`CPACK_IFW_PRODUCT_URL`

  URL to a page that contains product information on your web site.

`CPACK_IFW_PACKAGE_ICON`

  Filename for a custom installer icon. The actual file is ‘.icns’ (Mac OS X), ‘.ico’ (Windows). No functionality on Unix.

`CPACK_IFW_PACKAGE_WINDOW_ICON`

  Filename for a custom window icon in PNG format for the Installer application.

`CPACK_IFW_PACKAGE_LOGO`

  Filename for a logo is used as QWizard::LogoPixmap.

`CPACK_IFW_PACKAGE_START_MENU_DIRECTORY`

  Name of the default program group for the product in the Windows Start menu.

  By default used `CPACK_IFW_PACKAGE_NAME`.

`CPACK_IFW_TARGET_DIRECTORY`

  Default target directory for installation. By default used “@ApplicationsDir@/`CPACK_PACKAGE_INSTALL_DIRECTORY`“

  You can use predefined variables.

`CPACK_IFW_ADMIN_TARGET_DIRECTORY`

  Default target directory for installation with administrator rights.

  You can use predefined variables.

`CPACK_IFW_PACKAGE_GROUP`

  The group, which will be used to configure the root package

`CPACK_IFW_PACKAGE_NAME`

  The root package name, which will be used if configuration group is not specified

`CPACK_IFW_PACKAGE_MAINTENANCE_TOOL_NAME`

  Filename of the generated maintenance tool. The platform-specific executable file extension is appended.

  By default used QtIFW defaults (`maintenancetool`).

`CPACK_IFW_PACKAGE_MAINTENANCE_TOOL_INI_FILE`

  Filename for the configuration of the generated maintenance tool.

  By default used QtIFW defaults (`maintenancetool.ini`).

`CPACK_IFW_PACKAGE_ALLOW_NON_ASCII_CHARACTERS`

  Set to `ON` if the installation path can contain non-ASCII characters.

  Is `ON` for QtIFW less 2.0 tools.

`CPACK_IFW_PACKAGE_ALLOW_SPACE_IN_PATH`

  Set to `OFF` if the installation path cannot contain space characters.

  Is `ON` for QtIFW less 2.0 tools.

`CPACK_IFW_PACKAGE_CONTROL_SCRIPT`

  Filename for a custom installer control script.

`CPACK_IFW_PACKAGE_RESOURCES`

  List of additional resources (‘.qrc’ files) to include in the installer binary.

  You can use `cpack_ifw_add_package_resources()` command to resolve relative paths.

`CPACK_IFW_REPOSITORIES_ALL`

  The list of remote repositories.

  The default value of this variable is computed by CPack and contains all repositories added with command `cpack_ifw_add_repository()` or updated with command `cpack_ifw_update_repository()`.

`CPACK_IFW_DOWNLOAD_ALL`

  If this is `ON` all components will be downloaded. By default is `OFF` or used value from `CPACK_DOWNLOAD_ALL` if set

### Components

`CPACK_IFW_RESOLVE_DUPLICATE_NAMES`

  Resolve duplicate names when installing components with groups.

`CPACK_IFW_PACKAGES_DIRECTORIES`

  Additional prepared packages dirs that will be used to resolve dependent components.

### Tools

`CPACK_IFW_FRAMEWORK_VERSION`

  The version of used QtIFW tools.

`CPACK_IFW_BINARYCREATOR_EXECUTABLE`

  The path to “binarycreator” command line client.

  This variable is cached and can be configured user if need.

`CPACK_IFW_REPOGEN_EXECUTABLE`

  The path to “repogen” command line client.

  This variable is cached and can be configured user if need.

## Commands

The module defines the following commands:

`cpack_ifw_configure_component`

  Sets the arguments specific to the CPack IFW generator.

      cpack_ifw_configure_component(<compname> [COMMON] [ESSENTIAL]
                          [NAME <name>]
                          [VERSION <version>]
                          [SCRIPT <script>]
                          [PRIORITY <priority>]
                          [DEPENDS <com_id> ...]
                          [LICENSES <display_name> <file_path> ...]
                          [USER_INTERFACES <file_path> <file_path> ...])

  This command should be called after `cpack_add_component()` command.

  `COMMON`
    if set, then the component will be packaged and installed as part of a group to which it belongs.
  `ESSENTIAL`
    if set, then the package manager stays disabled until that component is updated.
  `NAME`
    is used to create domain-like identification for this component. By default used origin component name.
  `VERSION`
    is version of component. By default used `CPACK_PACKAGE_VERSION`.
  `SCRIPT`
    is a relative or absolute path to operations script for this component.
  `PRIORITY`
    is priority of the component in the tree.
  `DEPENDS`
    list of dependency component identifiers in QtIFW style.
  `LICENSES`
    pair of <display_name> and <file_path> of license text for this component. You can specify more then one license.
  `USER_INTERFACES`
    a list of <file_path> representing pages to load

`cpack_ifw_configure_component_group`

  Sets the arguments specific to the CPack IFW generator.

      cpack_ifw_configure_component_group(<groupname>
                          [NAME <name>]
                          [VERSION <version>]
                          [SCRIPT <script>]
                          [PRIORITY <priority>]
                          [LICENSES <display_name> <file_path> ...]
                          [USER_INTERFACES <file_path> <file_path> ...])

  This command should be called after `cpack_add_component_group()` command.

  `NAME`
    is used to create domain-like identification for this component group. By default used origin component group name.
  `VERSION`
    is version of component group. By default used `CPACK_PACKAGE_VERSION`.
  `SCRIPT`
    is a relative or absolute path to operations script for this component group.
  `PRIORITY`
    is priority of the component group in the tree.
  `LICENSES`
    pair of <display_name> and <file_path> of license text for this component group. You can specify more then one license.
  `USER_INTERFACES`
    a list of <file_path> representing pages to load

`cpack_ifw_add_repository`

  Add QtIFW specific remote repository to binary installer.

      cpack_ifw_add_repository(<reponame> [DISABLED]
                          URL <url>
                          [USERNAME <username>]
                          [PASSWORD <password>]
                          [DISPLAY_NAME <display_name>])

  This command will also add the <reponame> repository to a variable `CPACK_IFW_REPOSITORIES_ALL`.

  `DISABLED`
    if set, then the repository will be disabled by default.
  `URL`
    is points to a list of available components.
  `USERNAME`
    is used as user on a protected repository.
  `PASSWORD`
    is password to use on a protected repository.
  `DISPLAY_NAME`
    is string to display instead of the URL.

`cpack_ifw_update_repository`

  Update QtIFW specific repository from remote repository.

      cpack_ifw_update_repository(<reponame>
                          [[ADD|REMOVE] URL <url>]|
                           [REPLACE OLD_URL <old_url> NEW_URL <new_url>]]
                          [USERNAME <username>]
                          [PASSWORD <password>]
                          [DISPLAY_NAME <display_name>])

  This command will also add the <reponame> repository to a variable `CPACK_IFW_REPOSITORIES_ALL`.

  `URL`
    is points to a list of available components.
  `OLD_URL`
    is points to a list that will replaced.
  `NEW_URL`
    is points to a list that will replace to.
  `USERNAME`
    is used as user on a protected repository.
  `PASSWORD`
    is password to use on a protected repository.
  `DISPLAY_NAME`
    is string to display instead of the URL.

`cpack_ifw_add_package_resources`

  Add additional resources in the installer binary.

      cpack_ifw_add_package_resources(<file_path> <file_path> ...)

  This command will also add the specified files to a variable `CPACK_IFW_PACKAGE_RESOURCES`.

## Example usage

    set(CPACK_PACKAGE_NAME "MyPackage")
    set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "MyPackage Installation Example")
    set(CPACK_PACKAGE_VERSION "1.0.0") # Version of installer

    include(CPack)
    include(CPackIFW)

    cpack_add_component(myapp
        DISPLAY_NAME "MyApp"
        DESCRIPTION "My Application")
    cpack_ifw_configure_component(myapp
        VERSION "1.2.3" # Version of component
        SCRIPT "operations.qs")
    cpack_add_component(mybigplugin
        DISPLAY_NAME "MyBigPlugin"
        DESCRIPTION "My Big Downloadable Plugin"
        DOWNLOADED)
    cpack_ifw_add_repository(myrepo
        URL "http://example.com/ifw/repo/myapp"
        DISPLAY_NAME "My Application Repository")

## Online installer

By default CPack IFW generator makes offline installer. This means that all components will be packaged into a binary file.

To make a component downloaded, you must set the `DOWNLOADED` option in `cpack_add_component()`.

Then you would use the command `cpack_configure_downloads()`. If you set `ALL` option all components will be downloaded.

You also can use command `cpack_ifw_add_repository()` and variable `CPACK_IFW_DOWNLOAD_ALL` for more specific configuration.

CPack IFW generator creates “repository” dir in current binary dir. You would copy content of this dir to specified `site` (`url`).

## See Also

Qt Installer Framework Manual:

- Index page: http://doc.qt.io/qtinstallerframework/index.html
- Component Scripting: http://doc.qt.io/qtinstallerframework/scripting.html
- Predefined Variables: http://doc.qt.io/qtinstallerframework/scripting.html#predefined-variables
- Promoting Updates: http://doc.qt.io/qtinstallerframework/ifw-updates.html

Download Qt Installer Framework for you platform from Qt site:
  http://download.qt.io/official_releases/qt-installer-framework